Ci A Pi

If Abs(diff) > precisione And delta * diff > 0# Then delta = -delta / 5

'***************************************************************************
'%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
'***************************************************************************
'                        ASSE NEUTRO
'***************************************************************************
'%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
'***************************************************************************

' --------------------------------------------------------------------------
' Nome Sub          :determina_asse_neutro(
' Scopo funzione   : Calcola la posizione effettiva dell'asse neutro in modo
'                    che la somma algebrica delle risultanti di compressio-
'                    ne e trazione sia proprio Nd (sforzo normale di solle-
'                    citazione)
' Parametri formali: Struttura dati con tutti i poligoni che costituiscono la
'                    sezione, struttura dati con tutte le armature della se-
'                    zione. Nd=sforzo normale di sollecitazione.
'                    ult_snerv flag per determinare cosa si cerca, se Mr, Ms
'                    oppure momenti a data curvatura, curv=curvatura
' Valore restituito: Struttura dati con varie informazioni: risultanti di
'                    compressione e trazione, posizioni risultanti, posizio-
'                    ne asse neutro, deformazioni limite a rottura sezione
' Implementazione   : Luglio 2011
' Autore            : Zax2010
' traduzione in VBA : Afazio Settembre 2012
' modifica          : Tex Dicembre 2012
' --------------------------------------------------------------------------
Private Function asse_neutro_SLU(ByRef polic() As poligono_sezione, armco As armo_sezione, armcp As armp_sezione, nd As Double) As risultante_n_finale
Dim k As Integer
Dim Np As Integer
Dim npm As Integer                          'numero del poligono con il vertice di ordinata massima
Dim ymax As Double: ymax = -1000000#        'ordinata massima dei vertici della sezione
Dim yamin As Double: yamin = 1000000#       'ordinata minima delle armature
Dim Ntot As Double                          'sforzo normale risultante
Dim cont As Integer                         'contatore massimo numero di tentativi
Dim diff As Double                          'variabile ausiliaria
Dim yn As Double                            'posizione asse neutro
Dim delta As Double                         'variazione della posizione dell'asse neutro
Dim deform As deform_sezione                'configurazione deformata della sezione
Dim nc As risultante_n, nt As risultante_n

' Per prima cosa determina ymax della sezione di cls ed yamin della sezione di ferro
For Np = 1 To N_POLI
   If polic(Np).traz = 0 Then
       For k = 1 To polic(Np).numv
           If (polic(Np).Y(k) > ymax) Then
               'cls trave
               ymax = polic(Np).Y(k)
               npm = Np
           End If
       Next
   Else
       For k = 1 To polic(Np).numv
           If (polic(Np).Y(k) < yamin) Then
               'cls resistente a trazione
               yamin = polic(Np).Y(k)
           End If
       Next
   End If
Next
' Poi determina yamin tra tutte le armature
For k = 1 To armco.numarm
   If armco.Y(k) < yamin Then yamin = armco.Y(k)
Next
For k = 1 To armcp.numarm
   If armcp.Y(k) < yamin Then yamin = armcp.Y(k)
Next

' Quindi definisce un primo posizionamento dell'asse neutro
yn = yamin + 0.8 * (ymax - yamin)

'inizializzo contatore massimo numero di tentativi
cont = 0

'inizializzo variazione della posizione dell'asse neutro
'delta = 1250#
delta = TrovaDelta

' Inizia il ciclo iterativo alla ricerca della effettiva posizione dell'asse neutro
' procede con un ciclo a passo variabile, diminuendo il passo di scansione di ricerca
' della posizione dell'asse neutro ogni volta che la differenza tra ncompr ed ntraz cambia di segno
Const precisione As Double = 0.01
Const minDelta As Double = 0.000001

Do
   cont = cont + 1
  ' Calcola le deformazioni ultime della sezione
   deform = deform_ultime(polic, ymax, npm, yamin, yn)
   ' Calcola lo sforzo normale nella parte compressa della sezione
   nc = risult_compr(polic, armco, armcp, deform, ymax, yamin, yn)
   ' Calcola lo sforzo normale della parte tesa della sezione
   nt = risult_traz(polic, armco, armcp, deform, ymax, yamin, yn)
   ' Totale sforzo normale sulla sezione da confrontare con Nd
   Ntot = nc.n + nt.n
   diff = nd - Ntot
   If Abs(diff) > precisione And delta * diff > 0# Then delta = -delta / 5
   yn = yn + delta
   If cont = 250 Then Exit Do 'max 250 tentativi
Loop While Abs(diff) > precisione And Abs(delta) > minDelta

' Copia nella struttura dati i risultati definitivi con il posizionamento ultimo dell'asse neutro
asse_neutro_SLU.ncf.n = nc.n
asse_neutro_SLU.ncf.X = nc.X
asse_neutro_SLU.ncf.Y = nc.Y
asse_neutro_SLU.ntf.n = nt.n
asse_neutro_SLU.ntf.X = nt.X
asse_neutro_SLU.ntf.Y = nt.Y
asse_neutro_SLU.yn = yn
asse_neutro_SLU.epsc = deform.epsa
asse_neutro_SLU.epss = deform.epsb
asse_neutro_SLU.curv = deform.epsa / (ymax - yn)

End Function

'Calcoliamo delta
Private Function TrovaDelta() As Double
Dim n As Integer
Dim k As Integer
Dim xmin As Double, xmax As Double
Dim ymin As Double, ymax As Double
xmax = -1000000#
xmin = 1000000#
ymax = -1000000#
ymin = 1000000#

   For n = 1 To N_POLI
       For k = 1 To poli(n).numv
           If poli(n).X(k) < xmin Then xmin = poli(n).X(k)
           If poli(n).X(k) > xmax Then xmax = poli(n).X(k)
           If poli(n).Y(k) < ymin Then ymin = poli(n).Y(k)
           If poli(n).Y(k) > xmax Then xmax = poli(n).Y(k)
       Next k
   Next n

Dim base As Double
Dim altezza As Double

base = xmax - xmin
altezza = ymax - ymin

If base > altezza Then
   TrovaDelta = 1.5 * base
Else
   TrovaDelta = 1.5 * altezza
End If

End Function