Calcolo Paratie

Public Function alFa(cat_sol As String, H As Double) As Variant

Select Case cat_sol
   Case "A"
       alFa = 1
   Case "B"
       alFa = 1
      If H > 16 Then
           alFa = 1 - 0.38 / 34 * (H - 16)
           If alFa < 0.3 Then alFa = 0.3
      End If
   Case "C"
       alFa = 1
      If H > 8 Then
           alFa = 1 - 0.7 / 32 * (H - 8)
           If alFa < 0.3 Then alFa = 0.3
      End If
 
   Case "D"
       alFa = 1
      If H > 4 Then
           alFa = 1 - 0.7 / 16 * (H - 4)
           If alFa < 0.3 Then alFa = 0.3
      End If
   Case Else
       alFa = "N.B."
End Select

End Function

Public Function S_s(cat_sol As String, F0 As Double, ag_g As Double) As Variant

Select Case cat_sol
   Case "A"
       S_s = 1
   Case "B"
       S_s = Max(1, Min(1.2, 1.4 - 0.4 * F0 * ag_g))
   Case "C"
       S_s = Max(1, Min(1.5, 1.7 - 0.6 * F0 * ag_g))
   Case "D"
       S_s = Max(0.9, Min(1.8, 2.4 - 1.5 * F0 * ag_g))
   Case "E"
       S_s = Max(1#, Min(1.6, 2# - 1.1 * F0 * ag_g))
   Case Else
       S_s = "N.B."
End Select

End Function
'--------------------------------------
Public Function S_T(cat_topo As String) As Variant

Select Case cat_topo
   Case "T1"
       S_T = 1#
   Case "T2"
       S_T = 1.2
   Case "T3"
       S_T = 1.2
   Case "T4"
       S_T = 1.4

   Case Else
       S_T = "N.B."
End Select

End Function

Public Function Ka(fi As Double, alFa As Double, beta As Double, delta As Double, gammaFi As Double) As Variant
' La funzione calcola il coefficiente di spinta attiva in fase statica
' parametri in input:
' fi= angolo di attrito interno in gradi
' alfa: inclinazione del terrapieno rispetto all'orizzontale in gradi
' beta= inclinazione del paramento interno del muro rispetto all'orizzontale (se verticale beta=90°)
' delta= inclinazione della spinta rispetto alla normale al paramento interno (positivo se verso l'alto)
' gammaFi= coefficiente parziale per il parametri del terreno secondo M1 o M2
' tutti gli angoli in input sono in gradi sessadecimali

Pi = 4 * Atn(1)
fi = fi * Pi / 180
fi = Atn(Tan(fi) / gammaFi)
alFa = alFa * Pi / 180
beta = beta * Pi / 180
delta = delta * Pi / 180

K1 = (Sin(beta + fi)) ^ 2
k2 = (Sin(beta)) ^ 2 * Sin(beta - delta) * (1 + ((Sin(fi + delta) * Sin(fi - alFa)) / (Sin(beta - delta) * Sin(beta + alFa))) ^ 0.5) ^ 2

Ka = K1 / k2

End Function

Public Function Kas(fi As Double, alFa As Double, beta As Double, delta As Double, _
                   kh As Double, kv As Double, gammaFi As Double, flag As Integer) As Variant
'La funzione calcola il coefficiente di spinta attiva per la determinazione della
' spinta del terreno in fase sismica applicando i coefficiemti del DM2008
' parametri in input:
' fi= angolo di attrito interno in gradi
' alfa: inclinazione del terrapieno rispetto all'orizzontale in gradi
' beta= inclinazione del paramento interno del muro rispetto all'orizzontale (se verticale beta=90°)
' delta= inclinazione della spinta rispetto alla normale al paramento interno (positivo se verso l'alto)
' kh, kv =coefficienti sismici orizzontale e verticale
' gammaFi= coefficiente parziale per il parametri del terreno secondo M1 o M2
' flag= indicatore del tipo di sisma verticale che assume i seguenti valori
' sisma verticale verso il basso: flag=1
' sisma verticale verso l'alto: flag=2
' se a flag si attribuisce valore diverso da 1 o 2 si assume pari ad 1
' tutti gli angoli in input sono in gradi sessadecimali

Pi = 4 * Atn(1)
fi = fi * Pi / 180
fi = Atn(Tan(fi) / gammaFi)
alFa = alFa * Pi / 180
beta = beta * Pi / 180
delta = delta * Pi / 180

Select Case flag
Case Is = 1 'sisma verticale verso il basso
   Teta = Atn(kh / (1 - kv))
Case Is = 2 'sisma verticale verso l'alto
   Teta = Atn(kh / (1 + kv))
Case Else
   Teta = Atn(kh / (1 - kv))
End Select

K1 = (Sin(beta + fi - Teta)) ^ 2
k2 = Cos(Teta) * (Sin(beta)) ^ 2 * Sin(beta - delta - Teta)
k3 = 1
If alFa <= fi - Teta Then
k3 = (1 + ((Sin(fi + delta) * Sin(fi - alFa - Teta)) / (Sin(beta - delta - Teta) * Sin(beta + alFa))) ^ 0.5) ^ 2
End If

Kas = K1 / (k2 * k3)

End Function